This reference is for Processing 2.0+. If you have a previous version, use the reference included with your software. If you see any errors or have suggestions, please let us know. If you prefer a more technical reference, visit the Processing Javadoc.

Name

screenY()
Examples
void setup() {
  size(100, 100, P3D);
}

void draw() {
  background(204);
  
  float x = mouseX;
  float y = mouseY;
  float z = -100;
  
  // Draw "X" at z = -100
  stroke(255);
  line(x-10, y-10, z, x+10, y+10, z); 
  line(x+10, y-10, z, x-10, y+10, z); 
  
  // Draw gray line at z = 0 and same 
  // y value. Notice the parallax
  stroke(102);
  line(0, y, 0, width, y, 0);
  
  // Draw black line at z = 0 to match 
  // the y value element drawn at z = -100 
  stroke(0);
  float theY = screenY(x, y, z);
  line(0, theY, 0, width, theY, 0);    
}
Description Takes a three-dimensional X, Y, Z position and returns the Y value for where it will appear on a (two-dimensional) screen.
Syntax
screenY(x, y)
screenY(x, y, z)
Parameters
x float: 3D x-coordinate to be mapped
y float: 3D y-coordinate to be mapped
z float: 3D z-coordinate to be mapped
Returnsfloat
RelatedscreenX()
screenZ()
Updated on May 19, 2014 05:30:02pm PDT

Creative Commons License