Ball[] balls = new Ball[10]; 

void setup(){
  size(500,500);
  fill(255, 0, 0);
  smooth();
  ellipseMode(CENTER);
  
  //Create all new Ball objects
  for(int i=0; i<balls.length; i++){
    balls[i] = new Ball();
  }
}

void draw(){
   background(255);
   for(int i=0; i<balls.length; i++){
     balls[i].display();
     balls[i].update();
   }
}


class Ball{ //Definition of Ball
  //Fields
  float d; //diameter
  color c; //color
  float sx; //x position
  float sy; //y position
  float vx; //x velocity
  float vy; //y velocity
  float ay = 0.2; //y acceleration (gravity)
  float angle; // angle of rotation of the ball
  float vangle; //angular velocity of the ball
  
  //Constructor
  Ball(){
    sx = random(0.0, width);
    sy = random(0.0, height);
    vx = random(-3.0, 3.0);
    vy = random(-5.0, 5.0);
    c = color(random(0,255), random(0,255), random(0,255));
    d = random(5, 100);
    angle = random(0, TWO_PI);
    vangle = random(-0.1, 0.1);
  }
  
  //Define some behaviors
  void update(){
    //move the ball
    sx = sx + vx;
    sy += vy;
    vy += ay;
    angle += vangle; 
    
    //Bounce off the walls and floor
    if((sx<=d/2.0 && vx <0)||(sx >= (width -d/2.0) && vx>0)) 
      vx = -vx; 
    
    if( sy>= (height-d/2.0) && vy>0.0)
      vy = -0.9 *vy;
      
  }
  
  void display(){
    fill(c);
    pushMatrix();
    translate(sx, sy);
    
    //rotate the ball to the appropriate orientation
    rotate(angle);
    
    if(vx<0){
      scale(-1, 1);//horizontal image flip
    }
    
    //draw the body of the ball
    ellipse(0, 0, d,d);
    
    //draw white of the eye
    fill(255);
    ellipse(d/4, -d/8, d/4, d/4);
    
    //draw the pupil
    fill(0);
    ellipse(d/3.2, -d/8, d/16, d/16);
    popMatrix();
  }
}